nixos-config/flake.nix

{
  description = ''
    For questions just DM me on X: https://twitter.com/@m3tam3re
    There is also some NIXOS content on my YT channel: https://www.youtube.com/@m3tam3re

    One of the best ways to learn NIXOS is to read other peoples configurations. I have personally learned a lot from Gabriel Fontes configs:
    https://github.com/Misterio77/nix-starter-configs
    https://github.com/Misterio77/nix-config

    Please also check out the starter configs mentioned above.
  '';

  inputs = {
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    nixpkgs-stable.url = "github:nixos/nixpkgs/nixos-24.05";
    nixpkgs-a63367c.url = "github:nixos/nixpkgs/a63367cfcdb886bee208f50db8b069f61158861d";
    nixpkgs-master.url = "github:nixos/nixpkgs/master";

    hyprpanel.url = "github:Jas-SinghFSU/HyprPanel";

    dotfiles = {
      url = "git+https://code.m3tam3re.com/m3tam3re/dotfiles.git";
      flake = false;
    };
  };

  outputs = {
    self,
    dotfiles,
    home-manager,
    nixpkgs,
    ...
  } @ inputs: let
    inherit (self) outputs;
    systems = [
      "aarch64-linux"
      "i686-linux"
      "x86_64-linux"
      "aarch64-darwin"
      "x86_64-darwin"
    ];
    forAllSystems = nixpkgs.lib.genAttrs systems;
  in {
    packages =
      forAllSystems (system: import ./pkgs nixpkgs.legacyPackages.${system});
    overlays = import ./overlays {inherit inputs outputs;};
    homeManagerModules = import ./modules/home-manager;
    nixosConfigurations = {
      m3-kratos = nixpkgs.lib.nixosSystem {
        specialArgs = {
          inherit inputs outputs;
          hostname = "m3-kratos";
        };
        modules = [./hosts/m3-kratos];
      };
    };
    homeConfigurations = {
      "m3tam3re@m3-kratos" = home-manager.lib.homeManagerConfiguration {
        pkgs = nixpkgs.legacyPackages."x86_64-linux";
        extraSpecialArgs = {
          inherit inputs outputs;
          hostname = "m3-kratos";
        };
        modules = [./home/m3tam3re/m3tam3re.nix];
      };
    };
  };
}